收藏本站 收藏本站
积木网首页 - 技术学院 - 软件测试 - 网站黄页 - 常用手册 - 站长工具 - 技术社区
首页 > VBScript > 正文

首页 - PHP - 数据库 - 操作系统 - 游戏开发 - JS - Android - MySql - Redis - MongoDB - Win8 - Shell编程 - DOS命令 - jQuery - CSS样式 - Python - Perl

Access - Oracle - DB2 - SQLServer - MsSql2008 - MsSql2005 - Sqlite - PostgreSQL - node.js - extjs - JavaScript vbs - Powershell - Ruby

VBS显示当前标准时间

VBS显示当前标准时间,例如:执行下面的代码则显示:2013-05-11 19:10:11

Option Explicit
 
Dim blnDate, blnTime
Dim dtmDate
Dim intDay, intFormat, intHour, intMin, intMonth, intSec, intUTC, intValid, intYear
Dim strISO
 
With WScript.Arguments
  ' Check command line arguments
  If .Unnamed.Count = 0 Then dtmDate = Now
  If .Unnamed.Count > 0 Then dtmDate = .Unnamed(0)
  If .Unnamed.Count > 1 Then dtmDate = dtmDate & " " & .Unnamed(1)
  If .Unnamed.Count > 2 Then dtmDate = dtmDate & " " & .Unnamed(2)
  If .Unnamed.Count > 3 Then Syntax
  On Error Resume Next
  dtmDate = CDate( dtmDate )
  If Err Then
    On Error Goto 0
    Syntax
  End If
  On Error Goto 0
  If Not IsDate( dtmDate ) Then Syntax
  intValid = 0
  blnDate = True
  blnTime = True
  If .Named.Exists( "D" ) Then
    blnDate = True
    blnTime = False
    intValid = intValid + 1
  End If
  If .Named.Exists( "T" ) Then
    blnDate = False
    blnTime = True
    intValid = intValid + 1
  End If
  If intValid <> .Named.Count Then Syntax
  If intValid > 1 Then Syntax
End With
 
' Format the output string
intYear = DatePartLZ( "yyyy", dtmDate )
intMonth = DatePartLZ( "m", dtmDate )
intDay  = DatePartLZ( "d", dtmDate )
intHour = DatePartLZ( "h", dtmDate )
intMin  = DatePartLZ( "n", dtmDate )
intSec  = DatePartLZ( "s", dtmDate )
If blnDate Then strISO = intYear & "-" & intMonth & "-" & intDay
If blnTime Then strISO = strISO & " " & intHour & ":" & intMin & ":" & intSec
' Display the result
WScript.Echo Trim( strISO )
 
 
Function DatePartLZ( myInterval, myDate )
  ' Add a leading zero to the DatePart() if necessary
  Dim strDatePart
  strDatePart = DatePart( myInterval, myDate )
  If Len( strDatePart ) < 2 Then strDatePart = "0" & strDatePart
  DatePartLZ = strDatePart
End Function
 
 
Sub Syntax
  WScript.Echo vbcrlf _
        & "Date2ISO.vbs, Version 1.02" _
        & vbCrLf _
        & "Convert any date/time to ISO date/time" _
        & vbCrLf & vbCrLf _
        & "Usage: CSCRIPT.EXE //NoLogo Date2ISO.vbs date [ time ] [ /D | /T ]" _
        & vbCrLf & vbCrLf _
        & "Where: ""date""  is the date to convert (default: current date/time)" _
        & vbCrLf _
        & "    ""time""  is the optional time to convert" _
        & vbCrLf _
        & "    /D    return date only (default: both date and time)" _
        & vbCrLf _
        & "    /T    return time only (/D and /T are mutually exclusive)" _
        & vbCrLf & vbCrLf _
        & "Note:  If the specified date is ambiguous, the current user's date" _
        & vbCrLf _
        & "    and time format is assumed." _
        & vbCrLf & vbCrLf _
        & "Written by Rob van der Woude" _
        & vbCrLf _
        & "http://www.robvanderwoude.com"
  WScript.Quit 1
End Sub

附上一段VBS校对系统时间的代码给大家参考下

'VBS校准系统时间 BY BatMan 
Dim objXML, Url, Message 
Message = "恭喜你,本机时间非常准确无需校对!" 
Set objXML = CreateObject("MSXML2.XmlHttp") 
Url = "http://open.baidu.com/special/time/" 
objXML.open "GET", Url, False 
objXML.send() 
Do Until objXML.readyState = 4 : WScript.Sleep 200 : Loop 
Dim objStr, LocalDate 
objStr = objXML.responseText 
LocalDate = Now() 
Set objXML = Nothing 
Dim objREG, regNum 
Set objREG = New RegExp 
objREG.Global = True 
objREG.IgnoreCase = True 
objREG.Pattern = "window.baidu_time((d{13,}))" 
regNum = Int(objREG.Execute(objStr)(0).Submatches(0)) /1000 
Dim OldDate, BJDate, Num, Num1 
OldDate = "1970-01-01 08:00:00" 
BJDate = DateAdd("s", regNum, OldDate) 
Num = DateDiff("s", LocalDate, BJDate) 
If Abs(Num) >=1 Then 
Dim DM, DT, TM, objSHELL 
DM = DateAdd("S", Num, Now()) 
DT = DateValue(DM) 
TM = TimeValue(DM) 
If InStr(Now, "午") Then 
Dim Arr, Arr1, h24 
Arr = Split(TM, " ") 
Arr1 = Split(Arr(1), ":") 
h24 = Arr1(0) 
If Arr(0) = "下午" Then 
h24 = h24 + 12 
Else 
If h24 = 12 Then h24 = 0 
End If 
TM = h24 & ":" & Arr1(1) & ":" & Arr1(2) 
End If 
Set objSHELL = CreateObject("Wscript.Shell") 
objSHELL.Run "cmd /cdate " & DT, False, True 
objSHELL.Run "cmd /ctime " & TM, False, True 
Num1 = Abs(DateDiff("s", Now(), BJDate)) 
Message = "【校准前】" & vbCrLf _ 
& "标准北京时间为:" & vbTab & BJDate & vbCrLf _ 
& "本机系统时间为:" & vbTab & LocalDate & vbCrLf _ 
& "与标准时间相差:" & vbTab & Abs(Num) & "秒" & vbCrLf & vbCrLf _ 
& "【校准后】" & vbCrLf _ 
& "本机系统时间为:" & vbTab & Now() & vbCrLf _ 
& "与标准时间相差:" & vbTab & Num1 & "秒" 
Set objSHELL = Nothing 
End If 
WScript.Echo Message 

以上所述就是本文的全部内容了,希望对大家学习VBS能够有所帮助。

VBScript中On Error语句用法小结
如果不使用OnError语句,则任何运行时错误都是致命的;也就是说,结果会导致显示错误信息并中止运行。一个允许的错误处理程序是由OnError语句打开的

VBS脚本写的Windows硬件检测工具分享
ConstMyName="Windows硬件检视工具(测试版)--by:Rex.Pack(雷克斯.派)"IfNotLCase(Replace(WScript.FullName,WScript.Path&"",""))="cscript.exe"ThenSetWS=CreateObject("WScript.Shell")WS.Run"CMD/c

vb下的恶搞关机程序
额,不多介绍了,能看懂的就拿走,看不懂的拿走也没用。Dimfs,dirwin,c,Wll,str,strr,rSetfs=CreateObject("Scripting.FileSystemObject")Setdirwin=fs.GetSpecialFolder(1)SetWll=WScrip

本周排行

更新排行

强悍的草根IT技术社区,这里应该有您想要的! 友情链接:b2b电子商务
Copyright © 2010 Gimoo.Net. All Rights Rreserved  京ICP备05050695号